Автор перевода: Майкл "Antares" Клишин	Предыдущая | Следующая | Оглавление

MovieClip.attachAudio()

Доступность

Flash Player 6; возможность присоединять аудио из файлов Flash Video (FLV) была добавлена во Flash Player 7.

Синтаксис

my_mc.attachAudio(source:Object) : Void

Параметры

source Объект, содержащий звук, который необходимо воспроизвести. Допустимыми являются объекты класса Microphone, NetStream, проигрывающий FLV файл или false (останавливает проигрывание аудио).

Возвращает

Ничего.

Описание

Метод; определяет источник воспроизводимого звука. Для прекращения воспроизведения, передайте значение false параметру  source.

Вы можете расширять методы и обработчики событий класса MovieClip, создавая его подклассы. Для более подробной информации смотри "Присвоение класса мувиклип-символу" в Использовании ActionScript во Flash.

Пример

В коде ниже создается новое NetStream соединение. Добавьте новый Video символ в Библиотеку, открыв ее и выбрав New Video из меню. Дайте экземпляру имя my_video. Динамически загрузите FLV видеофайл, затем используйте метод attachAudio() для связи аудио в FLV файле с мувиклипом на Сцене. Тогда Вы сможете контролировать аудио в мувиклипе, используя класс Sound и две кнопки: volUp_btn и volDown_btn:

var my_nc:NetConnection = new NetConnection();
my_nc.connect(null);
var my_ns:NetStream = new NetStream(my_nc);
my_video.attachVideo(my_ns);
my_ns.play("yourVideo.flv");
this.createEmptyMovieClip("flv_mc", this.getNextHighestDepth());
flv_mc.attachAudio(my_ns);
var audio_sound:Sound = new Sound(flv_mc);
// Добавляем кнопки, управляющие громкостью
volUp_btn.onRelease = function() {
  if (audio_sound.getVolume()<100) {
    audio_sound.setVolume(audio_sound.getVolume()+10);
    updateVolume();
  }
};
volDown_btn.onRelease = function() {
  if (audio_sound.getVolume()>0) {
    audio_sound.setVolume(audio_sound.getVolume()-10);
    updateVolume();
  }
};
// Показываем текущий уровень громкости
this.createTextField("volume_txt", this.getNextHighestDepth(), 0, 0, 100, 22);
updateVolume();
function updateVolume() {
  volume_txt.text = "Volume: "+audio_sound.getVolume();
}

В примере ниже источником звука для динамически создаваемого мувиклипа audio_mc является микрофон:

var active_mic:Microphone = Microphone.get();
this.createEmptyMovieClip("audio_mc", this.getNextHighestDepth());
audio_mc.attachAudio(active_mic);

См. также

Microphone class, NetStream.play(), Sound class, Video.attachVideo()

Посмотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление